app-misc/anki/anki-2.1.16.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7 PYTHON_REQ_USE="sqlite"
   8
   9 inherit eutils python-single-r1 xdg
  10
  11 DESCRIPTION="A spaced-repetition memory training program (flash cards)"
  12 HOMEPAGE="https://apps.ankiweb.net"
  13 SRC_URI="https://apps.ankiweb.net/downloads/archive/${P}-source.tgz -> ${P}.tgz"
  14
  15 LICENSE="AGPL-3+"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="latex +recording +sound test"
  19 RESTRICT="!test? ( test )"
  20 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  21
  22 RDEPEND="${PYTHON_DEPS}
  23         $(python_gen_cond_dep '
  24                 >=dev-python/PyQt5-5.12[gui,svg,widgets,${PYTHON_MULTI_USEDEP}]
  25                 dev-python/PyQtWebEngine[${PYTHON_MULTI_USEDEP}]
  26                 dev-python/beautifulsoup:4[${PYTHON_MULTI_USEDEP}]
  27                 dev-python/decorator[${PYTHON_MULTI_USEDEP}]
  28                 dev-python/distro[${PYTHON_MULTI_USEDEP}]
  29                 dev-python/jsonschema[${PYTHON_MULTI_USEDEP}]
  30                 dev-python/markdown[${PYTHON_MULTI_USEDEP}]
  31                 dev-python/requests[${PYTHON_MULTI_USEDEP}]
  32                 dev-python/send2trash[${PYTHON_MULTI_USEDEP}]
  33         ')
  34         recording? ( media-sound/lame )
  35         sound? ( media-video/mpv )
  36         latex? (
  37                 app-text/texlive
  38                 app-text/dvipng
  39         )
  40 "
  41 DEPEND="${RDEPEND}
  42         test? (
  43                 $(python_gen_cond_dep '
  44                         dev-python/nose[${PYTHON_MULTI_USEDEP}]
  45                         dev-python/mock[${PYTHON_MULTI_USEDEP}]
  46                 ')
  47         )
  48 "
  49
  50 PATCHES=( "${FILESDIR}"/${PN}-2.1.0_beta25-web-folder.patch )
  51
  52 pkg_setup() {
  53         python-single-r1_pkg_setup
  54 }
  55
  56 src_prepare() {
  57         default
  58         sed -i -e "s/updates=True/updates=False/" \
  59                 aqt/profiles.py || die
  60 }
  61
  62 src_compile() {
  63         :;
  64 }
  65
  66 src_test() {
  67         sed -e "s:nose=nosetests$:nose=\"${EPYTHON} ${EROOT}usr/bin/nosetests\":" \
  68                 -i tools/tests.sh || die
  69         sed -e "s:nose=nosetests3$:nose=\"${EPYTHON} ${EROOT}usr/bin/nosetests3\":" \
  70                 -i tools/tests.sh || die
  71         sed -e "s:which nosetests3:which ${EROOT}usr/bin/nosetests3:" \
  72                 -i tools/tests.sh || die
  73         ./tools/tests.sh || die
  74 }
  75
  76 src_install() {
  77         doicon ${PN}.png
  78         domenu ${PN}.desktop
  79         doman ${PN}.1
  80
  81         dodoc README.md README.development
  82         python_domodule aqt anki
  83         python_newscript runanki anki
  84
  85         # Localization files go into the anki directory:
  86         python_moduleinto anki
  87         python_domodule locale
  88
  89         # not sure if this is correct, but
  90         # site-packages/aqt/mediasrv.py wants the directory
  91         insinto /usr/share/anki
  92         doins -r web
  93 }