app-portage/eix/eix-9999.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 EGIT_REPO_URI="git://git.berlios.de/eix"
   7
   8 WANT_AUTOMAKE="1.13"
   9 WANT_LIBTOOL="none"
  10
  11 PLOCALES="de ru"
  12 inherit autotools git-2 bash-completion-r1 eutils multilib l10n
  13
  14 DESCRIPTION="Search and query ebuilds, portage incl. local settings, ext. overlays, version changes, and more"
  15 HOMEPAGE="http://eix.berlios.de"
  16
  17 LICENSE="GPL-2"
  18 SLOT="0"
  19 KEYWORDS=""
  20 IUSE="clang debug +dep doc nls optimization security strong-optimization strong-security sqlite swap-remote tools"
  21
  22 BOTHDEPEND="sqlite? ( >=dev-db/sqlite-3 )
  23         nls? ( virtual/libintl )"
  24 RDEPEND="${BOTHDEPEND}
  25         app-shells/push"
  26 DEPEND="${BOTHDEPEND}
  27         clang? ( sys-devel/clang )
  28         doc? ( dev-python/docutils )
  29         >=sys-devel/gettext-0.18.3"
  30
  31 src_prepare() {
  32         epatch_user
  33         eautoreconf
  34 }
  35
  36 src_configure() {
  37         econf $(use_with sqlite) $(use_with doc extra-doc) \
  38                 $(use_enable nls) $(use_enable tools separate-tools) \
  39                 $(use_enable security) $(use_enable optimization) \
  40                 $(use_enable strong-security) \
  41                 $(use_enable strong-optimization) $(use_enable debug debugging) \
  42                 $(use_enable swap-remote) \
  43                 $(use_with prefix always-accept-keywords) \
  44                 $(use_with dep dep-default) \
  45                 $(use_with clang nongnu-cxx clang++) \
  46                 --with-zsh-completion \
  47                 --with-ebuild-sh-default="/usr/$(get_libdir)/portage/bin/ebuild.sh" \
  48                 --with-portage-rootpath="${ROOTPATH}" \
  49                 --with-eprefix-default="${EPREFIX}" \
  50                 --docdir="${EPREFIX}/usr/share/doc/${PF}" \
  51                 --htmldir="${EPREFIX}/usr/share/doc/${PF}/html"
  52 }
  53
  54 src_install() {
  55         default
  56         dobashcomp bash/eix
  57         keepdir "/var/cache/${PN}"
  58         fowners portage:portage "/var/cache/${PN}"
  59         fperms 775 "/var/cache/${PN}"
  60 }
  61
  62 pkg_postinst() {
  63         # fowners in src_install doesn't work for owner/group portage:
  64         # merging changes this owner/group back to root.
  65         use prefix || chown portage:portage "${EROOT}var/cache/${PN}"
  66         local obs="${EROOT}var/cache/eix.previous"
  67         ! test -f "${obs}" || ewarn "Found obsolete ${obs}, please remove it"
  68 }