app-portage/eix/eix-9999.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=4
   5
   6 EGIT_REPO_URI="git://git.berlios.de/eix"
   7
   8 WANT_LIBTOOL="none"
   9
  10 PLOCALES="de ru"
  11
  12 inherit autotools git-2 bash-completion-r1 eutils multilib l10n
  13
  14 DESCRIPTION="Search and query ebuilds, portage incl. local settings, ext. overlays, version changes, and more"
  15 HOMEPAGE="http://eix.berlios.de"
  16
  17 LICENSE="GPL-2"
  18 SLOT="0"
  19 KEYWORDS=""
  20 IUSE="clang debug +dep doc nls optimization security strong-optimization sqlite tools zsh-completion"
  21
  22 RDEPEND="app-shells/push
  23         sqlite? ( >=dev-db/sqlite-3 )
  24         nls? ( virtual/libintl )"
  25 DEPEND="${RDEPEND}
  26         clang? ( sys-devel/clang )
  27         doc? ( dev-python/docutils )
  28         sys-devel/gettext"
  29
  30 src_prepare() {
  31         epatch_user
  32         eautopoint
  33         eautoreconf
  34 }
  35
  36 src_configure() {
  37         econf $(use_with sqlite) $(use_with doc extra-doc) \
  38                 $(use_with zsh-completion) \
  39                 $(use_enable nls) $(use_enable tools separate-tools) \
  40                 $(use_enable security) $(use_enable optimization) \
  41                 $(use_enable strong-optimization) $(use_enable debug debugging) \
  42                 $(use_with prefix always-accept-keywords) \
  43                 $(use_with dep dep-default) \
  44                 $(use_with clang nongnu-cxx clang++) \
  45                 --with-ebuild-sh-default="/usr/$(get_libdir)/portage/bin/ebuild.sh" \
  46                 --with-portage-rootpath="${ROOTPATH}" \
  47                 --with-eprefix-default="${EPREFIX}" \
  48                 --docdir="${EPREFIX}/usr/share/doc/${PF}" \
  49                 --htmldir="${EPREFIX}/usr/share/doc/${PF}/html"
  50 }
  51
  52 src_install() {
  53         default
  54         dobashcomp bash/eix
  55         keepdir "/var/cache/${PN}"
  56         fowners portage:portage "/var/cache/${PN}"
  57         fperms 775 "/var/cache/${PN}"
  58 }
  59
  60 pkg_postinst() {
  61         # fowners in src_install doesn't work for owner/group portage:
  62         # merging changes this owner/group back to root.
  63         use prefix || chown portage:portage "${EROOT}var/cache/${PN}"
  64         local obs="${EROOT}var/cache/eix.previous"
  65         ! test -f "${obs}" || ewarn "Found obsolete ${obs}, please remove it"
  66 }