app-portage/eix/eix-9999.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=4
   5
   6 EGIT_REPO_URI="git://git.berlios.de/eix"
   7
   8 WANT_LIBTOOL="none"
   9
  10 inherit autotools git-2 multilib bash-completion-r1
  11
  12 DESCRIPTION="Search and query ebuilds, portage incl. local settings, ext. overlays, version changes, and more"
  13 HOMEPAGE="http://eix.berlios.de"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS=""
  18 IUSE="debug +dep doc nls optimization security strong-optimization sqlite tools zsh-completion"
  19
  20 RDEPEND="sqlite? ( >=dev-db/sqlite-3 )
  21         nls? ( virtual/libintl )
  22         zsh-completion? ( !!<app-shells/zsh-completion-20091203-r1 )"
  23 DEPEND="${RDEPEND}
  24         doc? ( dev-python/docutils )
  25         sys-devel/gettext"
  26
  27 src_prepare() {
  28         eautopoint
  29         eautoreconf
  30 }
  31
  32 src_configure() {
  33         econf $(use_with sqlite) $(use_with doc extra-doc) \
  34                 $(use_with zsh-completion) \
  35                 $(use_enable nls) $(use_enable tools separate-tools) \
  36                 $(use_enable security) $(use_enable optimization) \
  37                 $(use_enable strong-optimization) $(use_enable debug debugging) \
  38                 $(use_with prefix always-accept-keywords) \
  39                 $(use_with dep dep-default) \
  40                 --with-ebuild-sh-default="/usr/$(get_libdir)/portage/bin/ebuild.sh" \
  41                 --with-portage-rootpath="${ROOTPATH}" \
  42                 --with-eprefix-default="${EPREFIX}" \
  43                 --docdir="${EPREFIX}/usr/share/doc/${PF}" \
  44                 --htmldir="${EPREFIX}/usr/share/doc/${PF}/html"
  45 }
  46
  47 src_install() {
  48         default
  49         dobashcomp bash/eix
  50         keepdir "/var/cache/${PN}"
  51         fowners portage:portage "/var/cache/${PN}"
  52         fperms 775 "/var/cache/${PN}"
  53 }
  54
  55 pkg_postinst() {
  56         # fowners in src_install doesn't work for owner/group portage:
  57         # merging changes this owner/group back to root.
  58         use prefix || chown portage:portage "${EROOT}var/cache/${PN}"
  59         local obs="${EROOT}var/cache/eix.previous"
  60         ! test -f "${obs}" || ewarn "Found obsolete ${obs}, please remove it"
  61 }