]> git.bzium.org - embe/overlay.git/blob - app-portage/eix/eix-9999.ebuild
Aktualizacja app-portage/eix-9999
[embe/overlay.git] / app-portage / eix / eix-9999.ebuild
1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3
4 EAPI=6
5
6 EGIT_REPO_URI="https://github.com/vaeth/eix.git"
7
8 WANT_LIBTOOL="none"
9
10 PLOCALES="de ru"
11 inherit autotools git-r3 bash-completion-r1 l10n systemd
12
13 DESCRIPTION="Search and query ebuilds, portage incl. local settings, ext. overlays, version changes, and more"
14 HOMEPAGE="https://github.com/vaeth/eix/"
15
16 LICENSE="GPL-2"
17 SLOT="0"
18 KEYWORDS=""
19 IUSE="debug +dep doc nls optimization +required-use security strong-optimization strong-security sqlite swap-remote tools"
20
21 BOTHDEPEND="sqlite? ( >=dev-db/sqlite-3 )
22         nls? ( virtual/libintl )"
23 RDEPEND="${BOTHDEPEND}
24         app-shells/push"
25 DEPEND="${BOTHDEPEND}
26         doc? ( dev-python/docutils )
27         >=sys-devel/gettext-0.18.3"
28
29 src_prepare() {
30         sed -i -e "s'/'${EPREFIX}/'" -- "${S}"/tmpfiles.d/eix.conf || die
31         eapply_user
32         eautoreconf
33 }
34
35 src_configure() {
36         econf $(use_with sqlite) $(use_with doc extra-doc) \
37                 $(use_enable nls) $(use_enable tools separate-tools) \
38                 $(use_enable security) $(use_enable optimization) \
39                 $(use_enable strong-security) \
40                 $(use_enable strong-optimization) $(use_enable debug debugging) \
41                 $(use_enable swap-remote) \
42                 $(use_with prefix always-accept-keywords) \
43                 $(use_with dep dep-default) \
44                 $(use_with required-use required-use-default) \
45                 --with-zsh-completion \
46                 --with-portage-rootpath="${ROOTPATH}" \
47                 --with-eprefix-default="${EPREFIX}"
48 }
49
50 src_install() {
51         default
52         dobashcomp bash/eix
53         systemd_dotmpfilesd tmpfiles.d/eix.conf
54 }
55
56 pkg_postinst() {
57         test -d "${EROOT}var/cache/${PN}" || {
58                 mkdir "${EROOT}var/cache/${PN}"
59                 use prefix || chown portage:portage "${EROOT}var/cache/${PN}"
60         }
61         local obs="${EROOT}var/cache/eix.previous"
62         ! test -f "${obs}" || ewarn "Found obsolete ${obs}, please remove it"
63 }
64
65 pkg_postrm() {
66         [ -n "${REPLACED_BY_VERSION}" ] || rm -rf -- "${EROOT}var/cache/${PN}"
67 }