From 7f041f04bcec31af2d7fe696b259d471f6ea3f8d Mon Sep 17 00:00:00 2001
From: =?utf8?q?Micha=C5=82=20Bartoszkiewicz?= <mbartoszkiewicz@gmail.com>
Date: Thu, 21 May 2020 20:47:15 +0200
Subject: [PATCH 1/1] dev-python/cloudflare: new package

---
 dev-python/cloudflare/Manifest                |  1 +
 dev-python/cloudflare/cloudflare-2.7.1.ebuild | 46 +++++++++++++++++++
 2 files changed, 47 insertions(+)
 create mode 100644 dev-python/cloudflare/Manifest
 create mode 100644 dev-python/cloudflare/cloudflare-2.7.1.ebuild

diff --git a/dev-python/cloudflare/Manifest b/dev-python/cloudflare/Manifest
new file mode 100644
index 0000000..2f86999
--- /dev/null
+++ b/dev-python/cloudflare/Manifest
@@ -0,0 +1 @@
+DIST python-cloudflare-2.7.1.tar.gz 70085 BLAKE2B 311daf7a8069d93b1deb2839e4fc26506748639e63681012e07830d92f5840830a5a34e569e5ace44ff04932e2fce80a7e6e3d5e0e64fd5c4f9fe3c13020cc83 SHA512 26cc49320e3249b0855bbf2ca2a5749f26641d801c8de3e6684e3f1c794c79b4b4588a2fb02bbf33c566adc7e466da7c5b3d4ff5b35d774c2ee6c3d381503ff0
diff --git a/dev-python/cloudflare/cloudflare-2.7.1.ebuild b/dev-python/cloudflare/cloudflare-2.7.1.ebuild
new file mode 100644
index 0000000..687b4d7
--- /dev/null
+++ b/dev-python/cloudflare/cloudflare-2.7.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+MY_PN="python-${PN}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python wrapper for the Cloudflare Client API v4"
+HOMEPAGE="https://github.com/cloudflare/python-cloudflare"
+SRC_URI="https://github.com/cloudflare/${MY_PN}/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="MIT-with-advertising"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/future[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/jsonlines[${PYTHON_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	sed -i -e "s:packages=.*:packages=['cli4', 'CloudFlare'],:" -i setup.py || die
+	sed -i -e "/data_files = /d" -i setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	newman cli4/cli4.man cli4.1
+
+	distutils-r1_python_install_all
+}
-- 
2.45.2