From 07461f2817f49e52cd706bfdd3dcb249d86d3d95 Mon Sep 17 00:00:00 2001
From: =?utf8?q?Micha=C5=82=20Bartoszkiewicz?= <mbartoszkiewicz@gmail.com>
Date: Sun, 24 May 2020 15:17:18 +0200
Subject: [PATCH] app-misc/anki: import from ::gentoo

---
 app-misc/anki/Manifest                        |  1 +
 app-misc/anki/anki-2.1.13-r1.ebuild           | 98 +++++++++++++++++++
 .../files/anki-2.1.0_beta25-web-folder.patch  | 11 +++
 app-misc/anki/metadata.xml                    | 21 ++++
 4 files changed, 131 insertions(+)
 create mode 100644 app-misc/anki/Manifest
 create mode 100644 app-misc/anki/anki-2.1.13-r1.ebuild
 create mode 100644 app-misc/anki/files/anki-2.1.0_beta25-web-folder.patch
 create mode 100644 app-misc/anki/metadata.xml

diff --git a/app-misc/anki/Manifest b/app-misc/anki/Manifest
new file mode 100644
index 0000000..953ce4d
--- /dev/null
+++ b/app-misc/anki/Manifest
@@ -0,0 +1 @@
+DIST anki-2.1.13.tgz 4248906 BLAKE2B 82a2a9a556cbf3596af22a73a2865815561cdd408b249443fc7e144734fdc2b62317120db71475afd7b0d4027f19e53c47437132028ef78b158ec3624f54a33f SHA512 921ef48b16c0c8c83b85523aa0a5b828210b210cd51fa471f57e9aa6777a1aced30c7e24084ef0c2f14c9d846a19091923d13faaff7ed9075860fc23f8ba1cd3
diff --git a/app-misc/anki/anki-2.1.13-r1.ebuild b/app-misc/anki/anki-2.1.13-r1.ebuild
new file mode 100644
index 0000000..9c1a33e
--- /dev/null
+++ b/app-misc/anki/anki-2.1.13-r1.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_6 )
+PYTHON_REQ_USE="sqlite"
+
+inherit eutils python-single-r1 xdg
+
+DESCRIPTION="A spaced-repetition memory training program (flash cards)"
+HOMEPAGE="https://apps.ankiweb.net"
+SRC_URI="https://apps.ankiweb.net/downloads/current/${P}-source.tgz -> ${P}.tgz"
+
+S="${WORKDIR}/${P}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="latex +recording +sound test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		|| (
+			(
+				>=dev-python/PyQt5-5.12[gui,svg,widgets,${PYTHON_MULTI_USEDEP}]
+				dev-python/PyQtWebEngine[${PYTHON_MULTI_USEDEP}]
+			)
+			<dev-python/PyQt5-5.12[gui,svg,webengine,widgets,${PYTHON_MULTI_USEDEP}]
+		)
+		>=dev-python/httplib2-0.7.4[${PYTHON_MULTI_USEDEP}]
+		dev-python/beautifulsoup:4[${PYTHON_MULTI_USEDEP}]
+		dev-python/decorator[${PYTHON_MULTI_USEDEP}]
+		dev-python/markdown[${PYTHON_MULTI_USEDEP}]
+		dev-python/requests[${PYTHON_MULTI_USEDEP}]
+		dev-python/send2trash[${PYTHON_MULTI_USEDEP}]
+	')
+	recording? ( media-sound/lame )
+	sound? ( media-video/mpv )
+	latex? (
+		app-text/texlive
+		app-text/dvipng
+	)
+"
+DEPEND="${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/nose[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.1.0_beta25-web-folder.patch )
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed -i -e "s/updates=True/updates=False/" \
+		aqt/profiles.py || die
+}
+
+src_compile() {
+	:;
+}
+
+src_test() {
+	sed -e "s:nose=nosetests$:nose=\"${EPYTHON} ${EROOT}usr/bin/nosetests\":" \
+		-i tools/tests.sh || die
+	sed -e "s:nose=nosetests3$:nose=\"${EPYTHON} ${EROOT}usr/bin/nosetests3\":" \
+		-i tools/tests.sh || die
+	sed -e "s:which nosetests3:which ${EROOT}usr/bin/nosetests3:" \
+		-i tools/tests.sh || die
+	./tools/tests.sh || die
+}
+
+src_install() {
+	doicon ${PN}.png
+	domenu ${PN}.desktop
+	doman ${PN}.1
+
+	dodoc README.md README.development
+	python_domodule aqt anki
+	python_newscript runanki anki
+
+	# Localization files go into the anki directory:
+	python_moduleinto anki
+	python_domodule locale
+
+	# not sure if this is correct, but
+	# site-packages/aqt/mediasrv.py wants the directory
+	insinto /usr/share/anki
+	doins -r web
+}
diff --git a/app-misc/anki/files/anki-2.1.0_beta25-web-folder.patch b/app-misc/anki/files/anki-2.1.0_beta25-web-folder.patch
new file mode 100644
index 0000000..19b196c
--- /dev/null
+++ b/app-misc/anki/files/anki-2.1.0_beta25-web-folder.patch
@@ -0,0 +1,11 @@
+--- anki-2.1.0beta25/aqt/mediasrv.py
++++ anki-2.1.0beta25/aqt/mediasrv.py
+@@ -13,7 +13,7 @@
+ # locate web folder in source/binary distribution
+ def _getExportFolder():
+     # running from source?
+-    srcFolder = os.path.join(os.path.dirname(__file__), "..")
++    srcFolder = os.path.join(os.path.dirname(__file__), "..", "..", "..", "..", "share", "anki")
+     webInSrcFolder = os.path.abspath(os.path.join(srcFolder, "web"))
+     if os.path.exists(webInSrcFolder):
+         return webInSrcFolder
diff --git a/app-misc/anki/metadata.xml b/app-misc/anki/metadata.xml
new file mode 100644
index 0000000..b4fe64e
--- /dev/null
+++ b/app-misc/anki/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>patrick@gentoo.org</email>
+		<name>Patrick Lauer</name>
+	</maintainer>
+	<longdescription lang="en">
+		Anki is a program designed to help you remember facts
+		(such as words and phrases in a foreign language) as
+		quickly, easily and efficiently as possible.
+	</longdescription>
+	<use>
+		<flag name="recording">
+			Enable support for audio recording
+		</flag>
+		<flag name="sound">
+			Enable support for adding sound to cards
+		</flag>
+	</use>
+</pkgmetadata>
-- 
2.43.2