app-misc/anki/anki-2.1.13-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python3_6 )
   7 PYTHON_REQ_USE="sqlite"
   8
   9 inherit eutils python-single-r1 xdg
  10
  11 DESCRIPTION="A spaced-repetition memory training program (flash cards)"
  12 HOMEPAGE="https://apps.ankiweb.net"
  13 SRC_URI="https://apps.ankiweb.net/downloads/current/${P}-source.tgz -> ${P}.tgz"
  14
  15 S="${WORKDIR}/${P}"
  16
  17 LICENSE="AGPL-3"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE="latex +recording +sound test"
  21 RESTRICT="!test? ( test )"
  22 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  23
  24 RDEPEND="${PYTHON_DEPS}
  25         $(python_gen_cond_dep '
  26                 || (
  27                         (
  28                                 >=dev-python/PyQt5-5.12[gui,svg,widgets,${PYTHON_MULTI_USEDEP}]
  29                                 dev-python/PyQtWebEngine[${PYTHON_MULTI_USEDEP}]
  30                         )
  31                         <dev-python/PyQt5-5.12[gui,svg,webengine,widgets,${PYTHON_MULTI_USEDEP}]
  32                 )
  33                 >=dev-python/httplib2-0.7.4[${PYTHON_MULTI_USEDEP}]
  34                 dev-python/beautifulsoup:4[${PYTHON_MULTI_USEDEP}]
  35                 dev-python/decorator[${PYTHON_MULTI_USEDEP}]
  36                 dev-python/markdown[${PYTHON_MULTI_USEDEP}]
  37                 dev-python/requests[${PYTHON_MULTI_USEDEP}]
  38                 dev-python/send2trash[${PYTHON_MULTI_USEDEP}]
  39         ')
  40         recording? ( media-sound/lame )
  41         sound? ( media-video/mpv )
  42         latex? (
  43                 app-text/texlive
  44                 app-text/dvipng
  45         )
  46 "
  47 DEPEND="${RDEPEND}
  48         test? (
  49                 $(python_gen_cond_dep '
  50                         dev-python/nose[${PYTHON_MULTI_USEDEP}]
  51                 ')
  52         )
  53 "
  54
  55 PATCHES=( "${FILESDIR}"/${PN}-2.1.0_beta25-web-folder.patch )
  56
  57 pkg_setup() {
  58         python-single-r1_pkg_setup
  59 }
  60
  61 src_prepare() {
  62         default
  63         sed -i -e "s/updates=True/updates=False/" \
  64                 aqt/profiles.py || die
  65 }
  66
  67 src_compile() {
  68         :;
  69 }
  70
  71 src_test() {
  72         sed -e "s:nose=nosetests$:nose=\"${EPYTHON} ${EROOT}usr/bin/nosetests\":" \
  73                 -i tools/tests.sh || die
  74         sed -e "s:nose=nosetests3$:nose=\"${EPYTHON} ${EROOT}usr/bin/nosetests3\":" \
  75                 -i tools/tests.sh || die
  76         sed -e "s:which nosetests3:which ${EROOT}usr/bin/nosetests3:" \
  77                 -i tools/tests.sh || die
  78         ./tools/tests.sh || die
  79 }
  80
  81 src_install() {
  82         doicon ${PN}.png
  83         domenu ${PN}.desktop
  84         doman ${PN}.1
  85
  86         dodoc README.md README.development
  87         python_domodule aqt anki
  88         python_newscript runanki anki
  89
  90         # Localization files go into the anki directory:
  91         python_moduleinto anki
  92         python_domodule locale
  93
  94         # not sure if this is correct, but
  95         # site-packages/aqt/mediasrv.py wants the directory
  96         insinto /usr/share/anki
  97         doins -r web
  98 }