app-portage/eix/eix-9999.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 EGIT_REPO_URI="https://github.com/vaeth/eix.git"
   7
   8 WANT_LIBTOOL="none"
   9
  10 PLOCALES="de ru"
  11 inherit autotools git-r3 bash-completion-r1 l10n systemd
  12
  13 DESCRIPTION="Search and query ebuilds, portage incl. local settings, ext. overlays, version changes, and more"
  14 HOMEPAGE="https://github.com/vaeth/eix/"
  15
  16 LICENSE="GPL-2"
  17 SLOT="0"
  18 KEYWORDS=""
  19 IUSE="debug +dep doc nls optimization +required-use security strong-optimization strong-security sqlite swap-remote tools"
  20
  21 BOTHDEPEND="sqlite? ( >=dev-db/sqlite-3 )
  22         nls? ( virtual/libintl )"
  23 RDEPEND="${BOTHDEPEND}
  24         >=app-shells/push-2.0
  25         >=app-shells/quoter-3.0"
  26 DEPEND="${BOTHDEPEND}
  27         doc? ( dev-python/docutils )
  28         >=sys-devel/gettext-0.18.3"
  29
  30 src_prepare() {
  31         sed -i -e "s'/'${EPREFIX}/'" -- "${S}"/tmpfiles.d/eix.conf || die
  32         eapply_user
  33         eautoreconf
  34 }
  35
  36 src_configure() {
  37         econf $(use_with sqlite) $(use_with doc extra-doc) \
  38                 $(use_enable nls) $(use_enable tools separate-tools) \
  39                 $(use_enable security) $(use_enable optimization) \
  40                 $(use_enable strong-security) \
  41                 $(use_enable strong-optimization) $(use_enable debug debugging) \
  42                 $(use_enable swap-remote) \
  43                 $(use_with prefix always-accept-keywords) \
  44                 $(use_with dep dep-default) \
  45                 $(use_with required-use required-use-default) \
  46                 --with-zsh-completion \
  47                 --with-portage-rootpath="${ROOTPATH}" \
  48                 --with-eprefix-default="${EPREFIX}"
  49 }
  50
  51 src_install() {
  52         default
  53         dobashcomp bash/eix
  54         systemd_dotmpfilesd tmpfiles.d/eix.conf
  55 }
  56
  57 pkg_postinst() {
  58         test -d "${EROOT}var/cache/${PN}" || {
  59                 mkdir "${EROOT}var/cache/${PN}"
  60                 use prefix || chown portage:portage "${EROOT}var/cache/${PN}"
  61         }
  62         local obs="${EROOT}var/cache/eix.previous"
  63         ! test -f "${obs}" || ewarn "Found obsolete ${obs}, please remove it"
  64 }
  65
  66 pkg_postrm() {
  67         [ -n "${REPLACED_BY_VERSION}" ] || rm -rf -- "${EROOT}var/cache/${PN}"
  68 }