app-misc/anki/anki-2.1.13-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7 PYTHON_REQ_USE="sqlite"
   8
   9 inherit eutils python-single-r1 xdg
  10
  11 DESCRIPTION="A spaced-repetition memory training program (flash cards)"
  12 HOMEPAGE="https://apps.ankiweb.net"
  13 SRC_URI="https://apps.ankiweb.net/downloads/current/${P}-source.tgz -> ${P}.tgz"
  14
  15 S="${WORKDIR}/${P}"
  16
  17 LICENSE="AGPL-3"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE="latex +recording +sound test"
  21 RESTRICT="!test? ( test )"
  22 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  23
  24 RDEPEND="${PYTHON_DEPS}
  25         $(python_gen_cond_dep '
  26                 || (
  27                         (
  28                                 >=dev-python/PyQt5-5.12[gui,svg,widgets,${PYTHON_MULTI_USEDEP}]
  29                                 dev-python/PyQtWebEngine[${PYTHON_MULTI_USEDEP}]
  30                         )
  31                         <dev-python/PyQt5-5.12[gui,svg,webengine,widgets,${PYTHON_MULTI_USEDEP}]
  32                 )
  33                 >=dev-python/httplib2-0.7.4[${PYTHON_MULTI_USEDEP}]
  34                 dev-python/beautifulsoup:4[${PYTHON_MULTI_USEDEP}]
  35                 dev-python/decorator[${PYTHON_MULTI_USEDEP}]
  36                 dev-python/distro[${PYTHON_MULTI_USEDEP}]
  37                 dev-python/jsonschema[${PYTHON_MULTI_USEDEP}]
  38                 dev-python/markdown[${PYTHON_MULTI_USEDEP}]
  39                 dev-python/requests[${PYTHON_MULTI_USEDEP}]
  40                 dev-python/send2trash[${PYTHON_MULTI_USEDEP}]
  41         ')
  42         recording? ( media-sound/lame )
  43         sound? ( media-video/mpv )
  44         latex? (
  45                 app-text/texlive
  46                 app-text/dvipng
  47         )
  48 "
  49 DEPEND="${RDEPEND}
  50         test? (
  51                 $(python_gen_cond_dep '
  52                         dev-python/nose[${PYTHON_MULTI_USEDEP}]
  53                         dev-python/mock[${PYTHON_MULTI_USEDEP}]
  54                 ')
  55         )
  56 "
  57
  58 PATCHES=( "${FILESDIR}"/${PN}-2.1.0_beta25-web-folder.patch )
  59
  60 pkg_setup() {
  61         python-single-r1_pkg_setup
  62 }
  63
  64 src_prepare() {
  65         default
  66         sed -i -e "s/updates=True/updates=False/" \
  67                 aqt/profiles.py || die
  68 }
  69
  70 src_compile() {
  71         :;
  72 }
  73
  74 src_test() {
  75         sed -e "s:nose=nosetests$:nose=\"${EPYTHON} ${EROOT}usr/bin/nosetests\":" \
  76                 -i tools/tests.sh || die
  77         sed -e "s:nose=nosetests3$:nose=\"${EPYTHON} ${EROOT}usr/bin/nosetests3\":" \
  78                 -i tools/tests.sh || die
  79         sed -e "s:which nosetests3:which ${EROOT}usr/bin/nosetests3:" \
  80                 -i tools/tests.sh || die
  81         ./tools/tests.sh || die
  82 }
  83
  84 src_install() {
  85         doicon ${PN}.png
  86         domenu ${PN}.desktop
  87         doman ${PN}.1
  88
  89         dodoc README.md README.development
  90         python_domodule aqt anki
  91         python_newscript runanki anki
  92
  93         # Localization files go into the anki directory:
  94         python_moduleinto anki
  95         python_domodule locale
  96
  97         # not sure if this is correct, but
  98         # site-packages/aqt/mediasrv.py wants the directory
  99         insinto /usr/share/anki
 100         doins -r web
 101 }