app-portage/eix/eix-9999.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=4
   5
   6 EGIT_REPO_URI="git://git.berlios.de/eix"
   7
   8 WANT_LIBTOOL="none"
   9
  10 inherit autotools git-2 multilib bash-completion-r1
  11
  12 DESCRIPTION="Search and query ebuilds, portage incl. local settings, ext. overlays, version changes, and more"
  13 HOMEPAGE="http://eix.berlios.de"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS=""
  18 IUSE="debug +dep doc nls optimization security strong-optimization sqlite tools zsh-completion"
  19
  20 RDEPEND="sqlite? ( >=dev-db/sqlite-3 )
  21         nls? ( virtual/libintl )
  22         app-shells/push
  23         zsh-completion? ( !!<app-shells/zsh-completion-20091203-r1 )"
  24 DEPEND="${RDEPEND}
  25         doc? ( dev-python/docutils )
  26         sys-devel/gettext"
  27
  28 src_prepare() {
  29         eautopoint
  30         eautoreconf
  31 }
  32
  33 src_configure() {
  34         econf $(use_with sqlite) $(use_with doc extra-doc) \
  35                 $(use_with zsh-completion) \
  36                 $(use_enable nls) $(use_enable tools separate-tools) \
  37                 $(use_enable security) $(use_enable optimization) \
  38                 $(use_enable strong-optimization) $(use_enable debug debugging) \
  39                 $(use_with prefix always-accept-keywords) \
  40                 $(use_with dep dep-default) \
  41                 --with-ebuild-sh-default="/usr/$(get_libdir)/portage/bin/ebuild.sh" \
  42                 --with-portage-rootpath="${ROOTPATH}" \
  43                 --with-eprefix-default="${EPREFIX}" \
  44                 --docdir="${EPREFIX}/usr/share/doc/${PF}" \
  45                 --htmldir="${EPREFIX}/usr/share/doc/${PF}/html"
  46 }
  47
  48 src_install() {
  49         default
  50         dobashcomp bash/eix
  51         keepdir "/var/cache/${PN}"
  52         fowners portage:portage "/var/cache/${PN}"
  53         fperms 775 "/var/cache/${PN}"
  54 }
  55
  56 pkg_postinst() {
  57         # fowners in src_install doesn't work for owner/group portage:
  58         # merging changes this owner/group back to root.
  59         use prefix || chown portage:portage "${EROOT}var/cache/${PN}"
  60         local obs="${EROOT}var/cache/eix.previous"
  61         ! test -f "${obs}" || ewarn "Found obsolete ${obs}, please remove it"
  62 }